移動平均線クロスアラート - MT5カスタムインジケーター

//+------------------------------------------------------------------+
//|                                               MACrossAlert.mq5   |
//|                                          FX Trading Tools        |
//+------------------------------------------------------------------+
#property copyright "FX Trading Tools"
#property version   "1.00"
#property indicator_chart_window
#property indicator_buffers 4
#property indicator_plots   2

#property indicator_label1  "Buy Signal"
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrDodgerBlue
#property indicator_width1  3

#property indicator_label2  "Sell Signal"
#property indicator_type2   DRAW_ARROW
#property indicator_color2  clrOrangeRed
#property indicator_width2  3

input int            FastMAPeriod  = 20;
input int            SlowMAPeriod  = 50;
input ENUM_MA_METHOD MAMethod      = MODE_EMA;
input ENUM_APPLIED_PRICE AppliedPrice = PRICE_CLOSE;
input bool           EnableAlert   = true;
input bool           EnablePush    = false;

double BuyBuffer[];
double SellBuffer[];
double FastMABuffer[];
double SlowMABuffer[];

int fastMA_handle;
int slowMA_handle;

//+------------------------------------------------------------------+
int OnInit()
{
 SetIndexBuffer(0, BuyBuffer, INDICATOR_DATA);
 SetIndexBuffer(1, SellBuffer, INDICATOR_DATA);
 SetIndexBuffer(2, FastMABuffer, INDICATOR_CALCULATIONS);
 SetIndexBuffer(3, SlowMABuffer, INDICATOR_CALCULATIONS);

 PlotIndexSetInteger(0, PLOT_ARROW, 233);
 PlotIndexSetInteger(1, PLOT_ARROW, 234);

 PlotIndexSetDouble(0, PLOT_EMPTY_VALUE, 0.0);
 PlotIndexSetDouble(1, PLOT_EMPTY_VALUE, 0.0);

 fastMA_handle = iMA(_Symbol, PERIOD_CURRENT, FastMAPeriod, 0, MAMethod, AppliedPrice);
 slowMA_handle = iMA(_Symbol, PERIOD_CURRENT, SlowMAPeriod, 0, MAMethod, AppliedPrice);

 if(fastMA_handle == INVALID_HANDLE || slowMA_handle == INVALID_HANDLE)
 {
    Print("Failed to create MA handles");
    return INIT_FAILED;
 }

 IndicatorSetString(INDICATOR_SHORTNAME,
    "MA Cross Alert (" +
    IntegerToString(FastMAPeriod) + "/" +
    IntegerToString(SlowMAPeriod) + ")");

 return INIT_SUCCEEDED;
}

//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
              const int prev_calculated,
              const datetime &time[],
              const double &open[],
              const double &high[],
              const double &low[],
              const double &close[],
              const long &tick_volume[],
              const long &volume[],
              const int &spread[])
{
 if(rates_total < SlowMAPeriod) return 0;

 int copied1 = CopyBuffer(fastMA_handle, 0, 0, rates_total, FastMABuffer);
 int copied2 = CopyBuffer(slowMA_handle, 0, 0, rates_total, SlowMABuffer);

 if(copied1 <= 0 || copied2 <= 0) return 0;

 int start = (prev_calculated > 1) ? prev_calculated - 1 : SlowMAPeriod;

 for(int i = start; i < rates_total; i++)
 {
    BuyBuffer[i]  = 0.0;
    SellBuffer[i] = 0.0;

    // Golden Cross
    if(FastMABuffer[i] > SlowMABuffer[i] &&
       FastMABuffer[i-1] <= SlowMABuffer[i-1])
    {
       BuyBuffer[i] = low[i] - _Point * 20;

       if(i == rates_total - 1 && EnableAlert)
       {
          Alert(_Symbol + ": Golden Cross detected!");
          if(EnablePush)
             SendNotification(_Symbol + ": Golden Cross detected!");
       }
    }

    // Dead Cross
    if(FastMABuffer[i] < SlowMABuffer[i] &&
       FastMABuffer[i-1] >= SlowMABuffer[i-1])
    {
       SellBuffer[i] = high[i] + _Point * 20;

       if(i == rates_total - 1 && EnableAlert)
       {
          Alert(_Symbol + ": Dead Cross detected!");
          if(EnablePush)
             SendNotification(_Symbol + ": Dead Cross detected!");
       }
    }
 }

 return rates_total;
}
//+------------------------------------------------------------------+